在VB6中用命令行为模式控制GUI动作

　　请注意在列表1中ICommand使用了前缀I。这是接口的一个通俗的前缀符号，在多种语言中被广泛的应用。它的目的是帮助读者记住该模块只包含定义。同时还要注意所有的方向命令中都使用了Implements语句。这确保了每个类最少拥有ICommand接口。其结果是我可以定义一个ICommand变量，并给它指定实现了ICommand类的任何实例。

　　最后我还要指出，每个命令都保持了特定的Form（Form1）的指针。其原因在于Form1包含了自己的边界和我希望用命令操作的控件的信息。

　　建立GUI

　　该程序的GUI由Form1表现，它包含了一个图像（image）控件，在该控件中有一个球的位图。该窗体还包含了一个对象集合，我把这个集合作为先前命令的堆栈。通过把每条命令添加到该集合的末尾，以及从集合末尾弹出命令，我可以相反地跟踪命令的执行过程。从本质上来说，该集合扮演了堆栈的角色。我在命令执行之后压入（push）命令，弹出（pop）命令调用Undo操作。

　　为了演示Undo操作，我定义了Edit|Undo菜单和Edit|Rewind操作。Undo从堆栈中弹出一条命令并调用Undo。Rewind弹出所有命令，在每个命令上调用Undo。列表2包含了Form1的代码。

　　列表2

　　Option Explicit
Private stack As Collection
Private Const MOVEMENT_AMOUNT As Integer = 50
Private Sub AboutMenu_Click()
Const About As String = "Command Pattern Demo" + vbCrLf + _
"Copyright (c) 2004. All Rights Reserved" + vbCrLf + _
"Written By Paul Kimmel. pkimmel@softconcepts.com"
MsgBox About, vbInformation + vbOKOnly, "About"
End Sub
Private Sub ExitMenu_Click()
End
End Sub
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
Select Case KeyCode
Case vbKeyBack
UndoCommand
Case vbKeyLeft
Call ProcessCommand(New LeftCommand)
Case vbKeyUp
Call ProcessCommand(New UpCommand)
Case vbKeyRight
Call ProcessCommand(New RightCommand)
Case vbKeyDown
Call ProcessCommand(New DownCommand)
End Select
End Sub
Private Function PopStack() As ICommand
On Error GoTo Catch
Debug.Print "Stack count: " & stack.Count
If (stack.Count = 0) Then
Beep
Set PopStack = Nothing
Exit Function
End If
Set PopStack = stack.Item(stack.Count)
Call stack.Remove(stack.Count)
Exit Function
Catch:
Debug.Print Err.Description
Set PopStack = Nothing
End Function
Private Sub PushStack(ByVal command As ICommand)
On Error GoTo Catch
Call stack.Add(command)
Debug.Print "Stack count: " & stack.Count
Exit Sub
Catch:
Debug.Print Err.Description
End Sub
Public Sub UndoCommand()
Dim command As ICommand
Set command = PopStack()
If (command Is Nothing) Then Exit Sub
command.Undo
End Sub
Private Sub ProcessCommand(ByVal command As ICommand)
Set command.Form = Me
command.Execute
Call PushStack(command)
End Sub
Public Sub MoveDown()
Debug.Print "Moving Down"
If (Image1.Top > Height) Then
Image1.Top = 0 - Image1.Height + MOVEMENT_AMOUNT
Else
Image1.Top = Image1.Top + MOVEMENT_AMOUNT
End If
End Sub
Public Sub MoveUp()
Debug.Print "Moving Up"
If (Image1.Top + Image1.Height < 0) Then
Image1.Top = Height - MOVEMENT_AMOUNT
Else
Image1.Top = Image1.Top - MOVEMENT_AMOUNT
End If
End Sub
Public Sub MoveLeft()
Debug.Print "Moving Left"
If (Image1.Left + Image1.Width < 0) Then
Image1.Left = Width - MOVEMENT_AMOUNT
Else
Image1.Left = Image1.Left - MOVEMENT_AMOUNT
End If
End Sub
Public Sub MoveRight()
Debug.Print "Moving Right"
If (Image1.Left > Width) Then
Image1.Left = 0 - Image1.Width + MOVEMENT_AMOUNT
Else
Image1.Left = Image1.Left + MOVEMENT_AMOUNT
End If
End Sub
Private Sub Form_Load()
Set stack = New Collection
End Sub
Private Sub RewindMenu_Click()
While stack.Count > 0
UndoCommand
Wend
End Sub
Private Sub UndoMenu_Click()
Call UndoCommand
End Sub

[责任编辑:cndownzcom]